Hubbard correction (DFT+U)
In this example, we'll plot the DOS and projected DOS of Nickel Oxide with and without the Hubbard term correction.
using DFTK
using PseudoPotentialData
using Unitful
using UnitfulAtomic
using PlotsDefine the geometry and pseudopotential
a = 7.9 # Nickel Oxide lattice constant in Bohr
lattice = a * [[ 1.0 0.5 0.5];
[ 0.5 1.0 0.5];
[ 0.5 0.5 1.0]]
pseudopotentials = PseudoFamily("dojo.nc.sr.pbe.v0_4_1.standard.upf")
Ni = ElementPsp(:Ni, pseudopotentials)
O = ElementPsp(:O, pseudopotentials)
atoms = [Ni, O, Ni, O]
positions = [zeros(3), ones(3) / 4, ones(3) / 2, ones(3) * 3 / 4]
magnetic_moments = [2, 0, -1, 0]4-element Vector{Int64}:
2
0
-1
0First, we run an SCF and band computation without the Hubbard term
model = model_DFT(lattice, atoms, positions; temperature=5e-3,
functionals=PBE(), magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments))
bands = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands.εF > 0, bands.eigenvalues[1])
band_gap = bands.eigenvalues[1][lowest_unocc_band] - bands.eigenvalues[1][lowest_unocc_band-1]0.0821934196270585Then we plot the DOS and the PDOS for the relevant 3D (pseudo)atomic projector
εF = bands.εF
width = 5.0u"eV"
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands; εrange, colors=[1, 1])
plot_pdos(bands; p, iatom=1, label="3D", colors=[3, 4], εrange)
To perform and Hubbard computation, we have to define the Hubbard manifold and associated constant.
In DFTK there are a few ways to construct the OrbitalManifold. Here, we will apply the Hubbard correction on the 3D orbital of all nickel atoms. To select all nickel atoms, we can:
- Pass the
Nielement directly. - Pass the
:Nisymbol. - Pass the list of atom indices, here
[1, 3].
To select the orbitals, it is recommended to use their label, such as "3D" for PseudoDojo pseudopotentials.
Note that "manifold" is the standard term used in the literature for the set of atomic orbitals used to compute the Hubbard correction, but it is not meant in the mathematical sense.
U = 10u"eV"
# Alternative:
# manifold = OrbitalManifold(:Ni, "3D")
# Alternative:
# manifold = OrbitalManifold([1, 3], "3D")
manifold = OrbitalManifold(Ni, "3D")OrbitalManifold(Ni, "3D")Run SCF with a DFT+U setup, notice the extra_terms keyword argument, setting up the Hubbard +U term. It is also possible to set up multiple manifolds with different U values by passing each pair as a separate entry in the Hubbard constructor (i.e. Hubbard(manifold1 => U1, manifold2 => U2, etc.)) or as two vectors (i.e. Hubbard([manifold1, manifold2, etc.], [U1, U2, etc.])).
model = model_DFT(lattice, atoms, positions; extra_terms=[Hubbard(manifold => U)],
functionals=PBE(), temperature=5e-3, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments));n Energy log10(ΔE) log10(Δρ) Magnet |Magn| Diag Δtime
--- --------------- --------- --------- ------ ------ ---- ------
1 -361.3859276036 0.07 1.335 3.439 7.0 4.07s
2 -362.9632412369 0.20 -0.10 0.223 3.873 2.5 11.2s
3 -363.1924558249 -0.64 -0.20 0.000 3.776 3.1 2.54s
4 -363.2396613926 -1.33 -0.29 0.000 3.781 2.2 2.13s
5 -363.3694303997 -0.89 -0.30 0.000 3.688 4.1 3.58s
6 -363.3863223277 -1.77 -0.48 -0.000 3.657 2.1 2.11s
7 -363.3967963546 -1.98 -1.13 -0.000 3.676 2.8 2.30s
8 -363.3934785884 + -2.48 -0.90 0.000 3.677 2.0 2.64s
9 -363.3967475241 -2.49 -1.08 0.000 3.656 1.0 1.66s
10 -363.3975134185 -3.12 -1.38 0.000 3.645 1.5 1.80s
11 -363.3975990420 -4.07 -1.46 0.000 3.643 1.0 2.34s
12 -363.3976252803 -4.58 -1.48 0.000 3.643 1.0 1.70s
13 -363.3976627339 -4.43 -1.54 0.000 3.641 1.0 1.65s
14 -363.3976160141 + -4.33 -2.03 -0.000 3.654 1.0 1.66s
15 -363.3976578710 -4.38 -2.31 -0.000 3.654 1.0 2.29s
16 -363.3976265651 + -4.50 -2.18 -0.000 3.656 1.2 1.71s
17 -363.3976271631 -6.22 -2.19 -0.000 3.656 1.0 1.66s
18 -363.3976476758 -4.69 -2.25 -0.000 3.655 1.0 2.31s
19 -363.3976943686 -4.33 -2.56 -0.000 3.652 1.0 1.64s
20 -363.3977043916 -5.00 -2.82 -0.000 3.651 1.0 1.65s
21 -363.3977091995 -5.32 -3.31 0.000 3.649 1.9 1.83s
22 -363.3977099819 -6.11 -4.04 0.000 3.649 2.5 2.76s
23 -363.3977100059 -7.62 -4.10 0.000 3.648 2.2 2.11s
24 -363.3977100109 -8.29 -4.23 0.000 3.648 1.4 1.77s
25 -363.3977100128 -8.72 -4.27 0.000 3.648 1.0 2.25s
26 -363.3977100141 -8.89 -4.45 0.000 3.648 1.0 1.66s
27 -363.3977100164 -8.63 -4.80 0.000 3.648 1.1 1.67s
28 -363.3977100171 -9.17 -5.24 0.000 3.648 1.9 1.85s
29 -363.3977100174 -9.47 -5.04 0.000 3.648 2.9 2.76s
30 -363.3977100176 -9.86 -5.01 0.000 3.648 1.0 1.70s
31 -363.3977100177 -10.07 -5.03 0.000 3.648 1.4 1.79s
32 -363.3977100178 -10.05 -5.52 0.000 3.648 1.1 2.30s
33 -363.3977100178 -10.43 -5.43 0.000 3.648 2.1 2.05s
34 -363.3977100178 -10.70 -5.82 0.000 3.648 1.0 1.66s
35 -363.3977100178 -10.88 -5.89 0.000 3.648 1.8 1.87s
36 -363.3977100178 -11.01 -5.59 0.000 3.648 1.5 2.41s
37 -363.3977100178 -11.27 -5.59 0.000 3.648 1.8 1.86s
38 -363.3977100178 -11.53 -5.68 0.000 3.648 1.0 1.66s
39 -363.3977100179 -11.65 -6.38 0.000 3.648 1.0 1.67s
Run band computation
bands_hub = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands_hub.εF > 0, bands_hub.eigenvalues[1])
band_gap = bands_hub.eigenvalues[1][lowest_unocc_band] - bands_hub.eigenvalues[1][lowest_unocc_band-1]0.11667613255000397With the electron localization introduced by the Hubbard term, the band gap has now opened, reflecting the experimental insulating behaviour of Nickel Oxide.
εF = bands_hub.εF
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands_hub; p, colors=[2, 2], εrange)
plot_pdos(bands_hub; p, iatom=1, label="3D", colors=[3, 4], εrange)