Polarizability using automatic differentiation

Simple example for computing properties using (forward-mode) automatic differentiation. For a more classical approach and more details about computing polarizabilities, see Polarizability by linear response.

using DFTK
using LinearAlgebra
using ForwardDiff

# Construct PlaneWaveBasis given a particular electric field strength
# Again we take the example of a Helium atom.
function make_basis(ε::T; a=10., Ecut=30) where {T}
    lattice=T(a) * I(3)  # lattice is a cube of ``a`` Bohrs
    # Helium at the center of the box
    atoms     = [ElementPsp(:He; psp=load_psp("hgh/lda/He-q2"))]
    positions = [[1/2, 1/2, 1/2]]

    model = model_DFT(lattice, atoms, positions, [:lda_x, :lda_c_vwn];
                      extra_terms=[ExternalFromReal(r -> -ε * (r[1] - a/2))],
                      symmetries=false)
    PlaneWaveBasis(model; Ecut, kgrid=[1, 1, 1])  # No k-point sampling on isolated system
end

# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
    @assert isdiag(basis.model.lattice)
    a  = basis.model.lattice[1, 1]
    rr = [a * (r[1] - 1/2) for r in r_vectors(basis)]
    sum(rr .* ρ) * basis.dvol
end

# Function to compute the dipole for a given field strength
function compute_dipole(ε; tol=1e-8, kwargs...)
    scfres = self_consistent_field(make_basis(ε; kwargs...); tol)
    dipole(scfres.basis, scfres.ρ)
end;

With this in place we can compute the polarizability from finite differences (just like in the previous example):

polarizability_fd = let
    ε = 0.01
    (compute_dipole(ε) - compute_dipole(0.0)) / ε
end
1.7735583915379796

We do the same thing using automatic differentiation. Under the hood this uses custom rules to implicitly differentiate through the self-consistent field fixed-point problem.

polarizability = ForwardDiff.derivative(compute_dipole, 0.0)
println()
println("Polarizability via ForwardDiff:       $polarizability")
println("Polarizability via finite difference: $polarizability_fd")
n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime
---   ---------------   ---------   ---------   ----   ------
  1   -2.770881302769                   -0.52    9.0    158ms
  2   -2.772063749204       -2.93       -1.32    1.0    104ms
  3   -2.772083159404       -4.71       -2.49    1.0    147ms
  4   -2.772083359569       -6.70       -3.21    1.0    107ms
  5   -2.772083416760       -7.24       -3.98    2.0    122ms
  6   -2.772083417662       -9.04       -4.47    1.0    111ms
  7   -2.772083417807       -9.84       -5.37    1.0    145ms
  8   -2.772083417810      -11.52       -6.04    1.0    114ms
  9   -2.772083417811      -12.95       -6.75    1.0    131ms
 10   -2.772083417811      -14.07       -7.30    2.0    148ms
 11   -2.772083417811      -13.88       -7.88    1.0    128ms
 12   -2.772083417811      -15.35       -7.97    1.0    126ms
 13   -2.772083417811   +  -13.53       -8.46    1.0    127ms

Polarizability via ForwardDiff:       1.7725349622283422
Polarizability via finite difference: 1.7735583915379796