# Collinear spin and magnetic systems

In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.

First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.

using DFTK

a = 5.42352  # Bohr
lattice = a / 2 * [[-1  1  1];
[ 1 -1  1];
[ 1  1 -1]]
atoms = [Fe => [zeros(3)]];

To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.

kgrid = [3, 3, 3]  # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15          # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin, Ecut; kgrid=kgrid)

scfres_nospin = self_consistent_field(basis_nospin, tol=1e-6, mixing=KerkerMixing());
n     Free energy       Eₙ-Eₙ₋₁     ρout-ρin   Diag
---   ---------------   ---------   --------   ----
1   -16.64711012665         NaN   3.28e-01    4.8
2   -16.64775884398   -6.49e-04   7.79e-02    1.3
3   -16.64782454559   -6.57e-05   3.29e-03    1.5
4   -16.64783263828   -8.09e-06   1.94e-03    3.5
5   -16.64783417398   -1.54e-06   3.86e-04    1.3
6   -16.64783430446   -1.30e-07   1.05e-04    2.0
scfres_nospin.energies
Energy breakdown:
Kinetic             15.9217198
AtomicLocal         -5.0697350
AtomicNonlocal      -5.2207695
Ewald               -21.4723040
PspCorrection       1.8758831
Hartree             0.7794596
Xc                  -3.4438004
Entropy             -0.0182879

total               -16.647834304463


Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.

Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 2 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.

magnetic_moments = [Fe => [4, ]];
Units of the magnetisation and magnetic moments in DFTK

Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.

We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.

model = model_LDA(lattice, atoms, magnetic_moments=magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model, Ecut; kgrid=kgrid)
ρspin = guess_spin_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6, ρspin=ρspin, mixing=KerkerMixing());
n     Free energy       Eₙ-Eₙ₋₁     ρout-ρin   Magnet   Diag
---   ---------------   ---------   --------   ------   ----
1   -16.65997045575         NaN   3.41e-01    2.620    4.4
2   -16.66626255186   -6.29e-03   6.92e-02    2.428    1.1
3   -16.66693931925   -6.77e-04   8.37e-03    2.349    2.1
4   -16.66698661019   -4.73e-05   3.56e-03    2.320    2.3
5   -16.66699464808   -8.04e-06   6.20e-04    2.309    2.0
6   -16.66699627919   -1.63e-06   3.79e-04    2.301    2.3
7   -16.66699652134   -2.42e-07   2.36e-05    2.297    1.8
scfres.energies
Energy breakdown:
Kinetic             16.3014776
AtomicLocal         -5.2260219
AtomicNonlocal      -5.4135643
Ewald               -21.4723040
PspCorrection       1.8758831
Hartree             0.8201301
Xc                  -3.5395174
Entropy             -0.0130796

total               -16.666996521344

Model and magnetic moments

DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.

In direct comparison we notice the first, spin-paired calculation to be a little higher in energy

println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case:    ", scfres.energies.total)
println("Difference:       ", scfres.energies.total - scfres_nospin.energies.total);
No magnetization: -16.647834304462517
Magnetic case:    -16.666996521344103
Difference:       -0.019162216881586147

Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.

The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:

iup   = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];
(scfres.occupation[iup])[1:7] = [1.0, 0.9999988137652575, 0.9999988137506842, 0.9999988137275572, 0.9585630152217123, 0.9585627254771906, 1.1538292323459284e-29]
(scfres.occupation[idown])[1:7] = [1.0, 0.8328019667237734, 0.8328001790978184, 0.8327992712741157, 7.846806657680628e-6, 7.846649417265866e-6, 1.5498298860567122e-32]

Similarly the eigenvalues differ

@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];
(scfres.eigenvalues[iup])[1:7] = [-0.06926489767650797, 0.3568844882593395, 0.3568846111106434, 0.35688480606944806, 0.46191912518933687, 0.4619191981359221, 1.1596505550727074]
(scfres.eigenvalues[idown])[1:7] = [-0.03040903266831888, 0.4772755704767788, 0.4772756988581144, 0.47727576405456573, 0.6108857004597241, 0.610885900851082, 1.225777517905089]
k-points in collinear calculations

For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.

We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.

using Plots
plot_dos(scfres)

Similarly the band structure shows clear differences between both spin components.

using Unitful
using UnitfulAtomic
plot_bandstructure(scfres, kline_density=3, unit=u"hartree")