# Tutorial

This document provides an overview of the structure of the code and how to access basic information about calculations. Basic familiarity with the concepts of plane-wave density functional theory is assumed throughout. Feel free to take a look at the density-functional theory chapter for some introductory material on the topic.

We use rough parameters in order to be able to automatically generate this documentation very quickly. Therefore results are far from converged. Tighter thresholds and larger grids should be used for more realistic results.

For our discussion we will use the classic example of computing the LDA ground state of the silicon crystal. Performing such a calculation roughly proceeds in three steps.

```
using DFTK
using Plots
using Unitful
using UnitfulAtomic
# 1. Define lattice and atomic positions
a = 5.431u"angstrom" # Silicon lattice constant
lattice = a / 2 * [[0 1 1.]; # Silicon lattice vectors
[1 0 1.]; # specified column by column
[1 1 0.]]
```

3×3 Matrix{Unitful.Quantity{Float64, 𝐋, Unitful.FreeUnits{(Å,), 𝐋, nothing}}}: 0.0 Å 2.7155 Å 2.7155 Å 2.7155 Å 0.0 Å 2.7155 Å 2.7155 Å 2.7155 Å 0.0 Å

By default, all numbers passed as arguments are assumed to be in atomic units. Quantities such as temperature, energy cutoffs, lattice vectors, and the k-point grid spacing can optionally be annotated with Unitful units, which are automatically converted to the atomic units used internally. For more details, see the Unitful package documentation and the UnitfulAtomic.jl package.

```
# Load HGH pseudopotential for Silicon
Si = ElementPsp(:Si, psp=load_psp("hgh/lda/Si-q4"))
# Specify type and positions of atoms
atoms = [Si => [ones(3)/8, -ones(3)/8]]
# 2. Select model and basis
model = model_LDA(lattice, atoms)
kgrid = [4, 4, 4] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 7 # kinetic energy cutoff
# Ecut = 190.5u"eV" # Could also use eV or other energy-compatible units
basis = PlaneWaveBasis(model, Ecut; kgrid=kgrid)
# 3. Run the SCF procedure to obtain the ground state
scfres = self_consistent_field(basis, tol=1e-8);
```

n Energy Eₙ-Eₙ₋₁ ρout-ρin Diag --- --------------- --------- -------- ---- 1 -7.905185398878 NaN 1.95e-01 4.1 2 -7.909820581108 -4.64e-03 2.98e-02 1.0 3 -7.910014664110 -1.94e-04 3.04e-03 1.1 4 -7.910051880144 -3.72e-05 1.43e-03 2.5 5 -7.910052489316 -6.09e-07 9.42e-04 1.0 6 -7.910052842660 -3.53e-07 2.85e-05 1.0 7 -7.910052853886 -1.12e-08 1.72e-05 2.7 8 -7.910052854038 -1.52e-10 2.83e-06 1.0

That's it! Now you can get various quantities from the result of the SCF. For instance, the different components of the energy:

`scfres.energies`

Energy breakdown: Kinetic 3.0795117 AtomicLocal -2.1806302 AtomicNonlocal 1.7339372 Ewald -8.3979253 PspCorrection -0.2946254 Hartree 0.5417546 Xc -2.3920755 total -7.910052854038

Eigenvalues:

`hcat(scfres.eigenvalues...)`

7×10 Matrix{Float64}: -0.170181 -0.1318 -0.0883276 … -0.0562601 -0.11494 -0.0700165 0.201344 0.0909041 0.0122926 0.011115 0.0420622 0.0176505 0.249296 0.174773 0.176138 0.132964 0.220115 0.11233 0.249296 0.231428 0.20237 0.161043 0.220115 0.190456 0.350986 0.360027 0.340134 0.291807 0.320727 0.327376 0.369971 0.395898 0.389483 … 0.331814 0.38819 0.460263 0.369971 0.401676 0.412475 0.565554 0.38819 0.46272

`eigenvalues`

is an array (indexed by kpoints) of arrays (indexed by eigenvalue number). The "splatting" operation `...`

calls `hcat`

with all the inner arrays as arguments, which collects them into a matrix.

The resulting matrix is 7 (number of computed eigenvalues) by 8 (number of kpoints). There are 7 eigenvalues per kpoint because there are 4 occupied states in the system (4 valence electrons per silicon atom, two atoms per unit cell, and paired spins), and the eigensolver gives itself some breathing room by computing some extra states (see `n_ep_extra`

argument to `self_consistent_field`

).

We can check the occupations:

`hcat(scfres.occupation...)`

7×10 Matrix{Float64}: 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0

And density:

```
rvecs = collect(r_vectors(basis))[:, 1, 1] # slice along the x axis
x = [r[1] for r in rvecs] # only keep the x coordinate
plot(x, scfres.ρ.real[:, 1, 1], label="", xlabel="x", ylabel="ρ", marker=2)
```

We can also perform various postprocessing steps: for instance compute a band structure

`plot_bandstructure(scfres, kline_density=5)`

or get the cartesian forces (in Hartree / Bohr)

`compute_forces_cart(scfres)[1] # Select silicon forces`

2-element Vector{StaticArrays.SVector{3, Float64}}: [0.00044915368642274155, 0.000449159094131273, 0.00044915865511356416] [-0.0004491590941314691, -0.00044915368642262386, -0.00044915865511396444]

The `[1]`

extracts the forces for the first kind of atoms, i.e. `Si`

(silicon) in the setup of the `atoms`

list of step 1 above. As expected, they are almost zero in this highly symmetric configuration.

## Where to go from here

Take a look at the example index to continue exploring DFTK.