GitHub

Temperature and metallic systems

In this example we consider the modeling of a magnesium lattice as a simple example for a metallic system. For our treatment we will use the PBE exchange-correlation functional. First we import required packages and setup the lattice. Again notice that DFTK uses the convention that lattice vectors are specified column by column.

using DFTK
using Plots
using Unitful
using UnitfulAtomic

a = 3.01794  # bohr
b = 5.22722  # bohr
c = 9.77362  # bohr
lattice = [[-a -a  0]; [-b  b  0]; [0   0 -c]]
Mg = ElementPsp(:Mg; psp=load_psp("hgh/pbe/Mg-q2"))
atoms     = [Mg, Mg]
positions = [[2/3, 1/3, 1/4], [1/3, 2/3, 3/4]];

Next we build the PBE model and discretize it. Since magnesium is a metal we apply a small smearing temperature to ease convergence using the Fermi-Dirac smearing scheme. Note that both the Ecut is too small as well as the minimal $k$-point spacing kspacing far too large to give a converged result. These have been selected to obtain a fast execution time. By default PlaneWaveBasis chooses a kspacing of 2π * 0.022 inverse Bohrs, which is much more reasonable.

kspacing = 0.945 / u"angstrom"        # Minimal spacing of k-points,
#                                      in units of wavevectors (inverse Bohrs)
Ecut = 5                              # Kinetic energy cutoff in Hartree
temperature = 0.01                    # Smearing temperature in Hartree
smearing = DFTK.Smearing.FermiDirac() # Smearing method
#                                      also supported: Gaussian,
#                                      MarzariVanderbilt,
#                                      and MethfesselPaxton(order)

model = model_DFT(lattice, atoms, positions, [:gga_x_pbe, :gga_c_pbe];
                  temperature, smearing)
kgrid = kgrid_from_maximal_spacing(lattice, kspacing)
basis = PlaneWaveBasis(model; Ecut, kgrid);

Finally we run the SCF. Two magnesium atoms in our pseudopotential model result in four valence electrons being explicitly treated. Nevertheless this SCF will solve for eight bands by default in order to capture partial occupations beyond the Fermi level due to the employed smearing scheme. In this example we use a damping of 0.8. The default LdosMixing should be suitable to converge metallic systems like the one we model here. For the sake of demonstration we still switch to Kerker mixing here.

scfres = self_consistent_field(basis, damping=0.8, mixing=KerkerMixing());
n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime
---   ---------------   ---------   ---------   ----   ------
  1   -1.743325018289                   -1.28    5.0   32.2ms
  2   -1.743520912568       -3.71       -1.70    1.3   22.4ms
  3   -1.743613638252       -4.03       -2.84    4.3   33.8ms
  4   -1.743616696621       -5.51       -3.55    3.7   32.9ms
  5   -1.743616747861       -7.29       -4.56    3.5   32.1ms
  6   -1.743616749869       -8.70       -5.47    3.7   34.2ms
  7   -1.743616749884      -10.81       -6.44    3.2   31.3ms
scfres.occupation[1]
9-element Vector{Float64}:
 1.9999999999941416
 1.9985518367398591
 1.9905514422667883
 1.2449669865639436e-17
 1.2448817619660793e-17
 1.0289494012167445e-17
 1.0288618124520333e-17
 2.9884254354885515e-19
 1.6623549096190601e-21
scfres.energies
Energy breakdown (in Ha):
    Kinetic             0.7450615 
    AtomicLocal         0.3193180 
    AtomicNonlocal      0.3192776 
    Ewald               -2.1544222
    PspCorrection       -0.1026056
    Hartree             0.0061603 
    Xc                  -0.8615676
    Entropy             -0.0148387

    total               -1.743616749884

The fact that magnesium is a metal is confirmed by plotting the density of states around the Fermi level. To get better plots, we decrease the k spacing a bit for this step

kgrid_dos = kgrid_from_maximal_spacing(lattice, 0.7 / u"Å")
bands = compute_bands(scfres, kgrid_dos)
plot_dos(bands)
Example block output