Polarizability using automatic differentiation

Simple example for computing properties using (forward-mode) automatic differentiation. For a more classical approach and more details about computing polarizabilities, see Polarizability by linear response.

using DFTK
using LinearAlgebra
using ForwardDiff
using PseudoPotentialData

# Construct PlaneWaveBasis given a particular electric field strength
# Again we take the example of a Helium atom.
function make_basis(ε::T; a=10., Ecut=30) where {T}
    lattice = T(a) * I(3)  # lattice is a cube of ``a`` Bohrs
    # Helium at the center of the box
    pseudopotentials = PseudoFamily("cp2k.nc.sr.lda.v0_1.semicore.gth")
    atoms     = [ElementPsp(:He, pseudopotentials)]
    positions = [[1/2, 1/2, 1/2]]

    model = model_DFT(lattice, atoms, positions;
                      functionals=[:lda_x, :lda_c_vwn],
                      extra_terms=[ExternalFromReal(r -> -ε * (r[1] - a/2))],
                      symmetries=false)
    PlaneWaveBasis(model; Ecut, kgrid=[1, 1, 1])  # No k-point sampling on isolated system
end

# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
    @assert isdiag(basis.model.lattice)
    a  = basis.model.lattice[1, 1]
    rr = [a * (r[1] - 1/2) for r in r_vectors(basis)]
    sum(rr .* ρ) * basis.dvol
end

# Function to compute the dipole for a given field strength
function compute_dipole(ε; tol=1e-8, kwargs...)
    scfres = self_consistent_field(make_basis(ε; kwargs...); tol)
    dipole(scfres.basis, scfres.ρ)
end;

With this in place we can compute the polarizability from finite differences (just like in the previous example):

polarizability_fd = let
    ε = 0.01
    (compute_dipole(ε) - compute_dipole(0.0)) / ε
end

1.7735580066216372

We do the same thing using automatic differentiation. Under the hood this uses custom rules to implicitly differentiate through the self-consistent field fixed-point problem. This leads to a density-functional perturbation theory problem, which is automatically set up and solved in the background.

polarizability = ForwardDiff.derivative(compute_dipole, 0.0)
println()
println("Polarizability via ForwardDiff:       $polarizability")
println("Polarizability via finite difference: $polarizability_fd")

n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime 
---   ---------------   ---------   ---------   ----   ------
  1   -2.770667134261                   -0.52    8.0    152ms
  2   -2.772054831211       -2.86       -1.32    1.0    604ms
  3   -2.772083052533       -4.55       -2.46    1.0   91.5ms
  4   -2.772083324419       -6.57       -3.14    1.0   93.8ms
  5   -2.772083414084       -7.05       -3.74    2.0    134ms
  6   -2.772083417617       -8.45       -4.58    1.0   97.3ms
  7   -2.772083417807       -9.72       -5.15    2.0    117ms
  8   -2.772083417810      -11.52       -6.18    1.0    107ms
  9   -2.772083417811      -12.63       -6.81    2.0    118ms
 10   -2.772083417811      -13.95       -7.50    1.0    106ms
 11   -2.772083417811   +  -14.65       -7.89    2.0    126ms
 12   -2.772083417811      -14.75       -9.19    1.0    107ms
Solving response problem
Iter  Restart  Krydim  log10(res)  avg(CG)  Δtime   Comment
----  -------  ------  ----------  -------  ------  ---------------
                                      14.0  64.9ms  Non-interacting
   1        0       1       -0.60     11.0   233ms  
   2        0       2       -2.42      9.0   637ms  
   3        0       3       -3.55      7.0   108ms  
   4        0       4       -5.33      6.0   104ms  
   5        0       5       -7.93      3.0  96.7ms  
   6        0       6      -10.28      1.0  85.1ms  
   7        1       1       -8.65     13.0   219ms  Restart
   8        1       2      -10.66      1.0  84.1ms  
                                      14.0   127ms  Final orbitals

Polarizability via ForwardDiff:       1.7725349730688988
Polarizability via finite difference: 1.7735580066216372