Hubbard correction (DFT+U)
In this example, we'll plot the DOS and projected DOS of Nickel Oxide with and without the Hubbard term correction.
using DFTK
using PseudoPotentialData
using Unitful
using UnitfulAtomic
using PlotsDefine the geometry and pseudopotential
a = 7.9 # Nickel Oxide lattice constant in Bohr
lattice = a * [[ 1.0 0.5 0.5];
[ 0.5 1.0 0.5];
[ 0.5 0.5 1.0]]
pseudopotentials = PseudoFamily("dojo.nc.sr.pbe.v0_4_1.standard.upf")
Ni = ElementPsp(:Ni, pseudopotentials)
O = ElementPsp(:O, pseudopotentials)
atoms = [Ni, O, Ni, O]
positions = [zeros(3), ones(3) / 4, ones(3) / 2, ones(3) * 3 / 4]
magnetic_moments = [2, 0, -1, 0]4-element Vector{Int64}:
2
0
-1
0First, we run an SCF and band computation without the Hubbard term
model = model_DFT(lattice, atoms, positions; temperature=5e-3,
functionals=PBE(), magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments))
bands = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands.εF > 0, bands.eigenvalues[1])
band_gap = bands.eigenvalues[1][lowest_unocc_band] - bands.eigenvalues[1][lowest_unocc_band-1]0.08219341647343176Then we plot the DOS and the PDOS for the relevant 3D (pseudo)atomic projector
εF = bands.εF
width = 5.0u"eV"
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands; εrange, colors=[1, 1])
plot_pdos(bands; p, iatom=1, label="3D", colors=[3, 4], εrange)
To perform and Hubbard computation, we have to define the Hubbard manifold and associated constant.
In DFTK there are a few ways to construct the OrbitalManifold. Here, we will apply the Hubbard correction on the 3D orbital of all nickel atoms. To select all nickel atoms, we can:
- Pass the
Nielement directly. - Pass the
:Nisymbol. - Pass the list of atom indices, here
[1, 3].
To select the orbitals, it is recommended to use their label, such as "3D" for PseudoDojo pseudopotentials.
Note that "manifold" is the standard term used in the literature for the set of atomic orbitals used to compute the Hubbard correction, but it is not meant in the mathematical sense.
U = 10u"eV"
# Alternative:
# manifold = OrbitalManifold(:Ni, "3D")
# Alternative:
# manifold = OrbitalManifold([1, 3], "3D")
manifold = OrbitalManifold(Ni, "3D")OrbitalManifold(Ni, "3D")Run SCF with a DFT+U setup, notice the extra_terms keyword argument, setting up the Hubbard +U term. It is also possible to set up multiple manifolds with different U values by passing each pair as a separate entry in the Hubbard constructor (i.e. Hubbard(manifold1 => U1, manifold2 => U2, etc.)) or as two vectors (i.e. Hubbard([manifold1, manifold2, etc.], [U1, U2, etc.])).
model = model_DFT(lattice, atoms, positions; extra_terms=[Hubbard(manifold => U)],
functionals=PBE(), temperature=5e-3, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments));n Energy log10(ΔE) log10(Δρ) Magnet |Magn| Diag Δtime
--- --------------- --------- --------- ------ ------ ---- ------
1 -361.3867467060 0.07 1.335 3.439 6.9 4.18s
2 -362.9626552606 0.20 -0.10 0.223 3.874 2.5 11.8s
3 -363.1929256059 -0.64 -0.20 0.000 3.776 3.1 2.58s
4 -363.2397352656 -1.33 -0.29 0.000 3.782 2.2 2.21s
5 -363.3694571404 -0.89 -0.30 0.000 3.689 4.1 3.69s
6 -363.3864556064 -1.77 -0.48 -0.000 3.658 2.1 2.13s
7 -363.3967927900 -1.99 -1.13 -0.000 3.676 2.6 2.29s
8 -363.3934190116 + -2.47 -0.89 0.000 3.677 2.0 2.75s
9 -363.3967518680 -2.48 -1.08 0.000 3.656 1.0 1.72s
10 -363.3975182359 -3.12 -1.38 0.000 3.645 1.5 1.85s
11 -363.3976011897 -4.08 -1.46 0.000 3.643 1.0 2.39s
12 -363.3976286361 -4.56 -1.49 0.000 3.643 1.0 1.71s
13 -363.3976600709 -4.50 -1.53 0.000 3.641 1.0 1.75s
14 -363.3976615765 -5.82 -2.19 -0.000 3.651 1.0 1.70s
15 -363.3976756600 -4.85 -2.39 -0.000 3.653 1.0 2.36s
16 -363.3976612163 + -4.84 -2.30 -0.000 3.654 1.2 1.76s
17 -363.3976584784 + -5.56 -2.30 -0.000 3.654 1.0 1.69s
18 -363.3976767388 -4.74 -2.41 -0.000 3.653 1.0 1.70s
19 -363.3976783405 -5.80 -2.41 -0.000 3.653 1.0 2.36s
20 -363.3977049008 -4.58 -2.73 -0.000 3.650 1.0 1.73s
21 -363.3977022226 + -5.57 -2.68 0.000 3.651 1.0 1.69s
22 -363.3977067128 -5.35 -2.82 0.000 3.650 1.0 2.36s
23 -363.3977066257 + -7.06 -2.84 0.000 3.650 1.0 1.69s
24 -363.3977068548 -6.64 -2.86 0.000 3.650 1.0 1.69s
25 -363.3977074970 -6.19 -2.91 0.000 3.650 1.0 1.70s
26 -363.3977082448 -6.13 -2.99 0.000 3.649 1.0 2.35s
27 -363.3977099380 -5.77 -3.94 -0.000 3.649 1.1 1.71s
28 -363.3977100093 -7.15 -4.03 -0.000 3.648 3.1 2.36s
29 -363.3977100109 -8.77 -4.24 -0.000 3.648 1.0 2.35s
30 -363.3977100173 -8.20 -4.78 0.000 3.648 1.9 1.89s
31 -363.3977100173 -11.22 -4.79 0.000 3.648 1.5 1.75s
32 -363.3977100176 -9.49 -5.03 0.000 3.648 1.0 1.77s
33 -363.3977100178 -9.69 -5.62 0.000 3.648 2.0 2.50s
34 -363.3977100178 -10.74 -5.60 0.000 3.648 2.5 2.25s
35 -363.3977100178 -10.84 -5.88 0.000 3.648 1.9 1.84s
36 -363.3977100178 -11.43 -5.79 0.000 3.648 2.0 2.62s
37 -363.3977100178 -11.29 -5.95 0.000 3.648 1.0 1.69s
38 -363.3977100178 -11.10 -6.01 0.000 3.648 2.1 2.01s
Run band computation
bands_hub = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands_hub.εF > 0, bands_hub.eigenvalues[1])
band_gap = bands_hub.eigenvalues[1][lowest_unocc_band] - bands_hub.eigenvalues[1][lowest_unocc_band-1]0.11667633457938242With the electron localization introduced by the Hubbard term, the band gap has now opened, reflecting the experimental insulating behaviour of Nickel Oxide.
εF = bands_hub.εF
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands_hub; p, colors=[2, 2], εrange)
plot_pdos(bands_hub; p, iatom=1, label="3D", colors=[3, 4], εrange)