Collinear spin and magnetic systems

In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.

First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.

using DFTK

a = 5.42352  # Bohr
lattice = a / 2 * [[-1  1  1];
                   [ 1 -1  1];
                   [ 1  1 -1]]
Fe = ElementPsp(:Fe, psp=load_psp("hgh/lda/Fe-q8.hgh"))
atoms = [Fe => [zeros(3)]];

To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.

kgrid = [3, 3, 3]  # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15          # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin, Ecut; kgrid=kgrid)

scfres_nospin = self_consistent_field(basis_nospin, tol=1e-6, mixing=KerkerMixing());
n     Free energy       Eₙ-Eₙ₋₁     ρout-ρin   Diag
---   ---------------   ---------   --------   ----
  1   -16.64727396037         NaN   3.28e-01    5.5
  2   -16.64778030058   -5.06e-04   7.78e-02    1.0
  3   -16.64782851514   -4.82e-05   3.28e-03    1.3
  4   -16.64783289717   -4.38e-06   1.78e-03    3.0
  5   -16.64783418698   -1.29e-06   3.79e-04    1.5
  6   -16.64783430545   -1.18e-07   9.64e-05    2.0
scfres_nospin.energies
Energy breakdown:
    Kinetic             15.9217977
    AtomicLocal         -5.0697756
    AtomicNonlocal      -5.2208144
    Ewald               -21.4723040
    PspCorrection       1.8758831 
    Hartree             0.7794710 
    Xc                  -3.4438041
    Entropy             -0.0182880

    total               -16.647834305454

Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.

Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 2 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.

magnetic_moments = [Fe => [4, ]];
Units of the magnetisation and magnetic moments in DFTK

Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.

We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.

model = model_LDA(lattice, atoms, magnetic_moments=magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model, Ecut; kgrid=kgrid)
ρspin = guess_spin_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6, ρspin=ρspin, mixing=KerkerMixing());
n     Free energy       Eₙ-Eₙ₋₁     ρout-ρin   Magnet   Diag
---   ---------------   ---------   --------   ------   ----
  1   -16.65996473347         NaN   3.41e-01    2.620    4.5
  2   -16.66626310178   -6.30e-03   6.92e-02    2.428    1.0
  3   -16.66693986954   -6.77e-04   8.45e-03    2.349    2.3
  4   -16.66698653989   -4.67e-05   3.62e-03    2.320    2.3
  5   -16.66699461230   -8.07e-06   6.67e-04    2.309    1.8
  6   -16.66699628449   -1.67e-06   3.62e-04    2.301    2.3
  7   -16.66699652138   -2.37e-07   2.45e-05    2.297    1.9
scfres.energies
Energy breakdown:
    Kinetic             16.3014788
    AtomicLocal         -5.2260164
    AtomicNonlocal      -5.4135643
    Ewald               -21.4723040
    PspCorrection       1.8758831 
    Hartree             0.8201279 
    Xc                  -3.5395226
    Entropy             -0.0130791

    total               -16.666996521381
Model and magnetic moments

DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.

In direct comparison we notice the first, spin-paired calculation to be a little higher in energy

println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case:    ", scfres.energies.total)
println("Difference:       ", scfres.energies.total - scfres_nospin.energies.total);
No magnetization: -16.647834305453518
Magnetic case:    -16.666996521381094
Difference:       -0.019162215927575943

Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.

The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:

iup   = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];
(scfres.occupation[iup])[1:7] = [1.0, 0.9999988139223973, 0.9999988139192891, 0.9999988138987121, 0.9585669473434605, 0.95856652406833, 1.1539961538217734e-29]
(scfres.occupation[idown])[1:7] = [1.0, 0.8327011684304969, 0.8326993805209425, 0.8326985840682677, 7.841221473233262e-6, 7.841189028758387e-6, 1.549841651682339e-32]

Similarly the eigenvalues differ

@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];
(scfres.eigenvalues[iup])[1:7] = [-0.06926600536722155, 0.3568835540980911, 0.35688358030271594, 0.3568837537891601, 0.46191852580616743, 0.46191863238016295, 1.1596494991262363]
(scfres.eigenvalues[idown])[1:7] = [-0.03040757196153044, 0.4772831983846754, 0.47728332672454954, 0.4772833838952296, 0.610893211452946, 0.6108932528301683, 1.2257778326126854]
k-points in collinear calculations

For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.

We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.

using Plots
plot_dos(scfres)

Similarly the band structure shows clear differences between both spin components.

using Unitful
using UnitfulAtomic
plot_bandstructure(scfres, kline_density=3, unit=u"hartree")