Custom potential

We solve the 1D Gross-Pitaevskii equation with a custom potential. This is similar to Gross-Pitaevskii equation in 1D example and we show how to define local potentials attached to atoms, which allows for instance to compute forces. The custom potential is actually already defined as ElementGaussian in DFTK, and could be used as is.

using DFTK
using LinearAlgebra

First, we define a new element which represents a nucleus generating a Gaussian potential.

struct CustomPotential <: DFTK.Element
    α  # Prefactor
    L  # Width of the Gaussian nucleus
end

Some default values

CustomPotential() = CustomPotential(1.0, 0.5);

We extend the two methods providing access to the real and Fourier representation of the potential to DFTK.

function DFTK.local_potential_real(el::CustomPotential, r::Real)
    -el.α / (√(2π) * el.L) * exp(- (r / el.L)^2 / 2)
end
function DFTK.local_potential_fourier(el::CustomPotential, p::Real)
    # = ∫ V(r) exp(-ix⋅p) dx
    -el.α * exp(- (p * el.L)^2 / 2)
end

We set up the lattice. For a 1D case we supply two zero lattice vectors

a = 10
lattice = a .* [[1 0 0.]; [0 0 0]; [0 0 0]];

In this example, we want to generate two Gaussian potentials generated by two "nuclei" localized at positions $x_1$ and $x_2$, that are expressed in $[0,1)$ in fractional coordinates. $|x_1 - x_2|$ should be different from $0.5$ to break symmetry and get nonzero forces.

x1 = 0.2
x2 = 0.8
positions = [[x1, 0, 0], [x2, 0, 0]]
gauss     = CustomPotential()
atoms     = [gauss, gauss];

We setup a Gross-Pitaevskii model

C = 1.0
α = 2;
n_electrons = 1  # Increase this for fun
terms = [Kinetic(),
         AtomicLocal(),
         LocalNonlinearity(ρ -> C * ρ^α)]
model = Model(lattice, atoms, positions; n_electrons, terms,
              spin_polarization=:spinless);  # use "spinless electrons"

We discretize using a moderate Ecut and run a SCF algorithm to compute forces afterwards. As there is no ionic charge associated to gauss we have to specify a starting density and we choose to start from a zero density.

basis = PlaneWaveBasis(model; Ecut=500, kgrid=(1, 1, 1))
ρ = zeros(eltype(basis), basis.fft_size..., 1)
scfres = self_consistent_field(basis; tol=1e-5, ρ)
scfres.energies

Energy breakdown (in Ha):
    Kinetic             0.0380295 
    AtomicLocal         -0.3163465
    LocalNonlinearity   0.1212606 

    total               -0.157056406917

Computing the forces can then be done as usual:

compute_forces(scfres)

2-element Vector{StaticArraysCore.SVector{3, Float64}}:
 [-0.05568122694087184, -0.0, -0.0]
 [0.05568254843580042, -0.0, -0.0]

Extract the converged total local potential

tot_local_pot = DFTK.total_local_potential(scfres.ham)[:, 1, 1]; # use only dimension 1

Extract other quantities before plotting them

ρ = scfres.ρ[:, 1, 1, 1]        # converged density, first spin component
ψ_fourier = scfres.ψ[1][:, 1]   # first k-point, all G components, first eigenvector

101-element Vector{ComplexF64}:
     0.7397578698399124 - 0.6315587567193082im
    0.07602589920400436 - 0.06490643504100992im
   -0.09008006200484817 + 0.07690477418487314im
   -0.03913173141598797 + 0.03340836963899272im
   0.006829119272511761 - 0.00583017853113713im
   0.010391440750231254 - 0.008871527131597761im
  0.0014991549817150883 - 0.0012798572537478848im
 -0.0016679337074360233 + 0.0014239620578496456im
 -0.0007183980721185121 + 0.0006133066314030383im
 0.00010934651649323163 - 9.335762955966755e-5im
                        ⋮
 0.00010935123758976748 - 9.335208576583649e-5im
 -0.0007183835091893995 + 0.0006133245400620046im
 -0.0016679197626881248 + 0.0014239788046815991im
  0.0014991290092176185 - 0.0012798889890617365im
   0.010391409775315833 - 0.008871565666000869im
   0.006829026058710561 - 0.005830286347385952im
   -0.03913188604567528 + 0.03340818695808778im
    -0.0900801427732979 + 0.07690468110592057im
    0.07602619806770029 - 0.06490608522334317im

Transform the wave function to real space and fix the phase:

ψ = ifft(basis, basis.kpoints[1], ψ_fourier)[:, 1, 1]
ψ /= (ψ[div(end, 2)] / abs(ψ[div(end, 2)]));

using Plots
x = a * vec(first.(DFTK.r_vectors(basis)))
p = plot(x, real.(ψ), label="real(ψ)")
plot!(p, x, imag.(ψ), label="imag(ψ)")
plot!(p, x, ρ, label="ρ")
plot!(p, x, tot_local_pot, label="tot local pot")