Tutorial

This document provides an overview of the structure of the code and how to access basic information about calculations. Basic familiarity with the concepts of plane-wave density functional theory is assumed throughout. Feel free to take a look at the density-functional theory chapter for some introductory lectures and introductory material on the topic.

For our discussion we will use the classic example of computing the LDA ground state of the silicon crystal. Performing such a calculation roughly proceeds in three steps.

using DFTK
using Plots

# 1. Define lattice and atomic positions
a = 10.26  # Silicon lattice constant in Bohr
lattice = a / 2 * [[0 1 1.];  # Silicon lattice vectors
                   [1 0 1.];  # specified column by column
                   [1 1 0.]]

# Load HGH pseudopotential for Silicon
Si = ElementPsp(:Si, psp=load_psp("hgh/lda/Si-q4"))

# Specify type and positions of atoms
atoms = [Si => [ones(3)/8, -ones(3)/8]]

# 2. Select model and basis
model = model_LDA(lattice, atoms)
kgrid = [4, 4, 4]  # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 7           # kinetic energy cutoff in Hartree
basis = PlaneWaveBasis(model, Ecut; kgrid=kgrid)

# 3. Run the SCF procedure to obtain the ground state
scfres = self_consistent_field(basis, tol=1e-8);

n     Energy            Eₙ-Eₙ₋₁     ρout-ρin   Diag
---   ---------------   ---------   --------   ----
  1   -7.905258087904         NaN   1.95e-01    4.1
  2   -7.910013532235   -4.76e-03   2.98e-02    2.0
  3   -7.910098988055   -8.55e-05   3.25e-03    1.0
  4   -7.910108933662   -9.95e-06   6.19e-04    1.9
  5   -7.910109401499   -4.68e-07   7.81e-05    1.6
  6   -7.910109413874   -1.24e-08   1.38e-05    1.9
  7   -7.910109414108   -2.34e-10   1.26e-06    1.7

That's it! Now you can get various quantities from the result of the SCF. For instance, the different components of the energy:

scfres.energies

Energy breakdown:
    Kinetic             3.0807718 
    AtomicLocal         -2.1784469
    AtomicNonlocal      1.7341047 
    Ewald               -8.4004648
    PspCorrection       -0.2948928
    Hartree             0.5413900 
    Xc                  -2.3925715

    total               -7.910109414108

Eigenvalues:

hcat(scfres.eigenvalues...)

7×10 Array{Float64,2}:
 -0.170033  -0.13162    -0.088102   …  -0.0560206  -0.114743   -0.0697771
  0.201709   0.0912097   0.0125265      0.0114074   0.0423182   0.0179179
  0.249665   0.175086    0.176466       0.133226    0.220466    0.112584
  0.249665   0.231789    0.202704       0.16134     0.220466    0.190778
  0.351459   0.360507    0.340562       0.292133    0.321216    0.32774
  0.370379   0.396308    0.389909   …   0.332169    0.388572    0.460795
  0.370379   0.402093    0.412871       0.566115    0.388572    0.463173

eigenvalues is an array (indexed by kpoints) of arrays (indexed by eigenvalue number). The "splatting" operation ... calls hcat with all the inner arrays as arguments, which collects them into a matrix.

The resulting matrix is 7 (number of computed eigenvalues) by 8 (number of kpoints). There are 7 eigenvalues per kpoint because there are 4 occupied states in the system (4 valence electrons per silicon atom, two atoms per unit cell, and paired spins), and the eigensolver gives itself some breathing room by computing some extra states (see n_ep_extra argument to self_consistent_field).

We can check the occupations:

hcat(scfres.occupation...)

7×10 Array{Float64,2}:
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0
 0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0
 0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0

And density:

rvecs = collect(r_vectors(basis))[:, 1, 1]  # slice along the x axis
x = [r[1] for r in rvecs]                   # only keep the x coordinate
plot(x, scfres.ρ.real[:, 1, 1], label="", xlabel="x", ylabel="ρ", marker=2)

We can also perform various postprocessing steps: for instance compute a band structure

plot_bandstructure(scfres, kline_density=5, unit=:eV)

or forces

forces(scfres)[1]  # Select silicon forces

2-element Array{StaticArrays.SArray{Tuple{3},Float64,1,3},1}:
 [0.004623576405013319, 0.004623706824880104, 0.004623650825520698]
 [-0.00462370682488019, -0.004623576405017161, -0.004623650825520935]

The [1] extracts the forces for the first kind of atoms, i.e. Si (silicon) in the setup of the atoms list of step 1 above. As expected, they are almost zero in this highly symmetric configuration.

Where to go from here

Take a look at the example index to continue exploring DFTK.