Hubbard correction (DFT+U)
In this example, we'll plot the DOS and projected DOS of Nickel Oxide with and without the Hubbard term correction.
using DFTK
using PseudoPotentialData
using Unitful
using UnitfulAtomic
using PlotsDefine the geometry and pseudopotential
a = 7.9 # Nickel Oxide lattice constant in Bohr
lattice = a * [[ 1.0 0.5 0.5];
[ 0.5 1.0 0.5];
[ 0.5 0.5 1.0]]
pseudopotentials = PseudoFamily("dojo.nc.sr.pbe.v0_4_1.standard.upf")
Ni = ElementPsp(:Ni, pseudopotentials)
O = ElementPsp(:O, pseudopotentials)
atoms = [Ni, O, Ni, O]
positions = [zeros(3), ones(3) / 4, ones(3) / 2, ones(3) * 3 / 4]
magnetic_moments = [2, 0, -1, 0]4-element Vector{Int64}:
2
0
-1
0First, we run an SCF and band computation without the Hubbard term
model = model_DFT(lattice, atoms, positions; temperature=5e-3,
functionals=PBE(), magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments))
bands = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands.εF > 0, bands.eigenvalues[1])
band_gap = bands.eigenvalues[1][lowest_unocc_band] - bands.eigenvalues[1][lowest_unocc_band-1]0.08219361721610285Then we plot the DOS and the PDOS for the relevant 3D (pseudo)atomic projector
εF = bands.εF
width = 5.0u"eV"
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands; εrange, colors=[1, 1])
plot_pdos(bands; p, iatom=1, label="3D", colors=[3, 4], εrange)
To perform and Hubbard computation, we have to define the Hubbard manifold and associated constant.
In DFTK there are a few ways to construct the OrbitalManifold. Here, we will apply the Hubbard correction on the 3D orbital of all nickel atoms. To select all nickel atoms, we can:
- Pass the
Nielement directly. - Pass the
:Nisymbol. - Pass the list of atom indices, here
[1, 3].
To select the orbitals, it is recommended to use their label, such as "3D" for PseudoDojo pseudopotentials.
Note that "manifold" is the standard term used in the literature for the set of atomic orbitals used to compute the Hubbard correction, but it is not meant in the mathematical sense.
U = 10u"eV"
# Alternative:
# manifold = OrbitalManifold(:Ni, "3D")
# Alternative:
# manifold = OrbitalManifold([1, 3], "3D")
manifold = OrbitalManifold(Ni, "3D")OrbitalManifold(Ni, "3D")Run SCF with a DFT+U setup, notice the extra_terms keyword argument, setting up the Hubbard +U term. It is also possible to set up multiple manifolds with different U values by passing each pair as a separate entry in the Hubbard constructor (i.e. Hubbard(manifold1 => U1, manifold2 => U2, etc.)) or as two vectors (i.e. Hubbard([manifold1, manifold2, etc.], [U1, U2, etc.])).
model = model_DFT(lattice, atoms, positions; extra_terms=[Hubbard(manifold => U)],
functionals=PBE(), temperature=5e-3, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments));┌ Warning: Negative ρcore detected: -0.0006182370306135084
└ @ DFTK ~/work/DFTK.jl/DFTK.jl/src/terms/xc.jl:39
n Energy log10(ΔE) log10(Δρ) Magnet |Magn| Diag Δtime
--- --------------- --------- --------- ------ ------ ---- ------
1 -361.3856920986 0.07 1.335 3.440 7.0 4.19s
2 -363.2381480061 0.27 -0.21 0.014 3.624 3.4 9.15s
3 -363.3511069021 -0.95 -0.58 0.000 3.727 3.2 2.90s
4 -363.3890312373 -1.42 -1.18 0.000 3.717 2.6 2.98s
5 -363.3959815630 -2.16 -1.67 0.000 3.681 2.0 2.19s
6 -363.3973171137 -2.87 -2.04 0.000 3.656 1.5 1.90s
7 -363.3976119556 -3.53 -2.28 0.000 3.648 2.5 2.74s
8 -363.3976915551 -4.10 -2.63 0.000 3.647 1.2 1.88s
9 -363.3977068940 -4.81 -2.99 0.000 3.649 2.1 2.19s
10 -363.3977058774 + -5.99 -2.91 -0.000 3.649 2.4 2.67s
11 -363.3977092962 -5.47 -3.18 0.000 3.648 2.0 2.08s
12 -363.3977078326 + -5.83 -3.04 0.000 3.648 2.0 2.14s
13 -363.3977091058 -5.90 -3.11 -0.000 3.648 2.1 2.74s
14 -363.3977088404 + -6.58 -3.00 -0.000 3.648 1.0 1.76s
15 -363.3977089788 -6.86 -2.97 -0.000 3.649 1.0 1.75s
16 -363.3977092575 -6.55 -3.10 -0.000 3.649 1.0 1.76s
17 -363.3977095628 -6.52 -3.11 -0.000 3.649 1.0 2.32s
18 -363.3977097890 -6.65 -3.23 0.000 3.649 1.0 1.75s
19 -363.3977098929 -6.98 -3.44 0.000 3.649 1.0 1.72s
20 -363.3977099658 -7.14 -3.54 0.000 3.648 1.0 2.22s
21 -363.3977100107 -7.35 -4.23 0.000 3.648 1.6 1.74s
22 -363.3977100124 -8.76 -4.30 0.000 3.648 2.6 2.10s
23 -363.3977100101 + -8.63 -4.26 0.000 3.648 1.1 1.66s
24 -363.3977100126 -8.60 -4.32 0.000 3.648 1.0 2.21s
25 -363.3977100157 -8.51 -4.27 0.000 3.648 1.1 1.66s
26 -363.3977100158 -10.51 -4.21 0.000 3.648 1.0 1.63s
27 -363.3977100155 + -9.62 -4.15 0.000 3.648 1.4 1.71s
28 -363.3977100137 + -8.72 -4.20 -0.000 3.648 1.0 2.20s
29 -363.3977100137 -10.32 -4.29 -0.000 3.648 1.0 1.64s
30 -363.3977100159 -8.66 -4.50 -0.000 3.648 1.0 1.63s
31 -363.3977100176 -8.78 -5.02 0.000 3.648 1.0 2.20s
32 -363.3977100178 -9.65 -5.47 0.000 3.648 2.4 1.95s
33 -363.3977100178 -10.28 -5.74 0.000 3.648 2.4 2.10s
34 -363.3977100178 -11.33 -5.89 0.000 3.648 1.0 1.64s
35 -363.3977100179 -11.41 -6.01 0.000 3.648 2.0 2.56s
Run band computation
bands_hub = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands_hub.εF > 0, bands_hub.eigenvalues[1])
band_gap = bands_hub.eigenvalues[1][lowest_unocc_band] - bands_hub.eigenvalues[1][lowest_unocc_band-1]0.11667597994884782With the electron localization introduced by the Hubbard term, the band gap has now opened, reflecting the experimental insulating behaviour of Nickel Oxide.
εF = bands_hub.εF
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands_hub; p, colors=[2, 2], εrange)
plot_pdos(bands_hub; p, iatom=1, label="3D", colors=[3, 4], εrange)