Polarizability using automatic differentiation

Simple example for computing properties using (forward-mode) automatic differentiation. For a more classical approach and more details about computing polarizabilities, see Polarizability by linear response.

using DFTK
using LinearAlgebra
using ForwardDiff
using PseudoPotentialData

# Construct PlaneWaveBasis given a particular electric field strength
# Again we take the example of a Helium atom.
function make_basis(ε::T; a=10., Ecut=30) where {T}
    lattice = T(a) * I(3)  # lattice is a cube of ``a`` Bohrs
    # Helium at the center of the box
    pseudopotentials = PseudoFamily("cp2k.nc.sr.lda.v0_1.semicore.gth")
    atoms     = [ElementPsp(:He, pseudopotentials)]
    positions = [[1/2, 1/2, 1/2]]

    model = model_DFT(lattice, atoms, positions;
                      functionals=[:lda_x, :lda_c_vwn],
                      extra_terms=[ExternalFromReal(r -> -ε * (r[1] - a/2))],
                      symmetries=false)
    PlaneWaveBasis(model; Ecut, kgrid=[1, 1, 1])  # No k-point sampling on isolated system
end

# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
    @assert isdiag(basis.model.lattice)
    a  = basis.model.lattice[1, 1]
    rr = [a * (r[1] - 1/2) for r in r_vectors(basis)]
    sum(rr .* ρ) * basis.dvol
end

# Function to compute the dipole for a given field strength
function compute_dipole(ε; tol=1e-8, kwargs...)
    scfres = self_consistent_field(make_basis(ε; kwargs...); tol)
    dipole(scfres.basis, scfres.ρ)
end;

With this in place we can compute the polarizability from finite differences (just like in the previous example):

polarizability_fd = let
    ε = 0.01
    (compute_dipole(ε) - compute_dipole(0.0)) / ε
end

1.7735580758802827

We do the same thing using automatic differentiation. Under the hood this uses custom rules to implicitly differentiate through the self-consistent field fixed-point problem. This leads to a density-functional perturbation theory problem, which is automatically set up and solved in the background.

polarizability = ForwardDiff.derivative(compute_dipole, 0.0)
println()
println("Polarizability via ForwardDiff:       $polarizability")
println("Polarizability via finite difference: $polarizability_fd")

n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime
---   ---------------   ---------   ---------   ----   ------
  1   -2.770848433961                   -0.52    9.0    246ms
  2   -2.772062853996       -2.92       -1.32    1.0   98.6ms
  3   -2.772083084025       -4.69       -2.45    1.0    132ms
  4   -2.772083346085       -6.58       -3.16    1.0    102ms
  5   -2.772083417365       -7.15       -4.15    2.0    124ms
  6   -2.772083417724       -9.45       -4.64    1.0    110ms
  7   -2.772083417808      -10.07       -5.87    1.0    113ms
  8   -2.772083417811      -11.64       -6.18    2.0    128ms
  9   -2.772083417811      -13.32       -6.92    1.0    114ms
 10   -2.772083417811      -13.78       -7.68    2.0    131ms
 11   -2.772083417811   +  -14.07       -8.36    1.0    114ms
Solving response problem
Iter  Restart  Krydim  log10(res)  avg(CG)  Δtime   Comment
----  -------  ------  ----------  -------  ------  ---------------
                                      13.0  71.2ms  Non-interacting
   1        0       1       -0.60     10.0   219ms
   2        0       2       -2.42      8.0   122ms
   3        0       3       -3.55      6.0   112ms
   4        0       4       -5.33      5.0   107ms
   5        0       5       -7.70      2.0  93.5ms
   6        0       6      -10.32      1.0  88.8ms
   7        1       1       -7.95     12.0   224ms  Restart
   8        1       2       -9.84      1.0  88.0ms
                                      13.0   132ms  Final orbitals

Polarizability via ForwardDiff:       1.7725349687043084
Polarizability via finite difference: 1.7735580758802827