Hubbard correction (DFT+U)
In this example, we'll plot the DOS and projected DOS of Nickel Oxide with and without the Hubbard term correction.
using DFTK
using PseudoPotentialData
using Unitful
using UnitfulAtomic
using PlotsDefine the geometry and pseudopotential
a = 7.9 # Nickel Oxide lattice constant in Bohr
lattice = a * [[ 1.0 0.5 0.5];
[ 0.5 1.0 0.5];
[ 0.5 0.5 1.0]]
pseudopotentials = PseudoFamily("dojo.nc.sr.pbe.v0_4_1.standard.upf")
Ni = ElementPsp(:Ni, pseudopotentials)
O = ElementPsp(:O, pseudopotentials)
atoms = [Ni, O, Ni, O]
positions = [zeros(3), ones(3) / 4, ones(3) / 2, ones(3) * 3 / 4]
magnetic_moments = [2, 0, -1, 0]4-element Vector{Int64}:
2
0
-1
0First, we run an SCF and band computation without the Hubbard term
model = model_DFT(lattice, atoms, positions; temperature=5e-3,
functionals=PBE(), magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments))
bands = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands.εF > 0, bands.eigenvalues[1])
band_gap = bands.eigenvalues[1][lowest_unocc_band] - bands.eigenvalues[1][lowest_unocc_band-1]0.08219315583617742Then we plot the DOS and the PDOS for the relevant 3D (pseudo)atomic projector
εF = bands.εF
width = 5.0u"eV"
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands; εrange, colors=[:red, :red])
plot_pdos(bands; p, iatom=1, label="3D", colors=[:yellow, :orange], εrange)
To perform and Hubbard computation, we have to define the Hubbard manifold and associated constant.
In DFTK there are a few ways to construct the OrbitalManifold. Here, we will apply the Hubbard correction on the 3D orbital of all nickel atoms. To select all nickel atoms, we can:
- Pass the
Nielement directly. - Pass the
:Nisymbol. - Pass the list of atom indices, here
[1, 3].
To select the orbitals, it is recommended to use their label, such as "3D" for PseudoDojo pseudopotentials.
Note that "manifold" is the standard term used in the literature for the set of atomic orbitals used to compute the Hubbard correction, but it is not meant in the mathematical sense.
U = 10u"eV"
# Alternative:
# manifold = OrbitalManifold(:Ni, "3D")
# Alternative:
# manifold = OrbitalManifold([1, 3], "3D")
manifold = OrbitalManifold(Ni, "3D")OrbitalManifold(Ni, "3D")Run SCF with a DFT+U setup, notice the extra_terms keyword argument, setting up the Hubbard +U term. It is also possible to set up multiple manifolds with different U values by passing each pair as a separate entry in the Hubbard constructor (i.e. Hubbard(manifold1 => U1, manifold2 => U2, etc.)) or as two vectors (i.e. Hubbard([manifold1, manifold2, etc.], [U1, U2, etc.])).
model = model_DFT(lattice, atoms, positions; extra_terms=[Hubbard(manifold => U)],
functionals=PBE(), temperature=5e-3, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments));┌ Warning: Negative ρcore detected: -0.0006182370306135084
└ @ DFTK ~/work/DFTK.jl/DFTK.jl/src/terms/xc.jl:39
n Energy log10(ΔE) log10(Δρ) Magnet |Magn| Diag Δtime
--- --------------- --------- --------- ------ ------ ---- ------
1 -361.3854685653 0.07 1.334 3.440 6.9 4.13s
2 -363.2378180350 0.27 -0.21 0.014 3.624 3.2 8.53s
3 -363.3511444518 -0.95 -0.58 0.000 3.727 3.4 3.55s
4 -363.3890342275 -1.42 -1.18 0.000 3.716 2.6 2.43s
5 -363.3959926428 -2.16 -1.67 0.000 3.681 2.0 2.23s
6 -363.3973129525 -2.88 -2.04 0.000 3.656 1.5 2.49s
7 -363.3976111855 -3.53 -2.29 0.000 3.647 2.2 2.16s
8 -363.3976910512 -4.10 -2.62 0.000 3.647 1.4 1.92s
9 -363.3977065431 -4.81 -2.97 0.000 3.649 2.0 2.75s
10 -363.3977062168 + -6.49 -2.92 -0.000 3.649 2.0 1.99s
11 -363.3977089848 -5.56 -3.15 -0.000 3.649 1.2 1.81s
12 -363.3977095265 -6.27 -3.16 -0.000 3.648 1.5 2.41s
13 -363.3977095595 -7.48 -3.10 -0.000 3.648 1.0 1.80s
14 -363.3977094355 + -6.91 -2.88 -0.000 3.648 1.0 1.77s
15 -363.3977074252 + -5.70 -2.90 -0.000 3.649 2.0 2.74s
16 -363.3977088645 -5.84 -3.17 -0.000 3.649 1.0 1.78s
17 -363.3977098872 -5.99 -3.44 0.000 3.649 1.9 1.97s
18 -363.3977099793 -7.04 -3.81 0.000 3.648 1.2 2.28s
19 -363.3977100026 -7.63 -4.14 0.000 3.648 2.1 2.04s
20 -363.3977100105 -8.10 -4.17 0.000 3.648 1.2 1.68s
21 -363.3977099473 + -7.20 -3.74 0.000 3.648 2.1 2.08s
22 -363.3977100063 -7.23 -3.79 -0.000 3.648 2.0 2.67s
23 -363.3977100140 -8.12 -3.99 0.000 3.648 1.0 1.68s
24 -363.3977100149 -9.06 -4.11 0.000 3.648 1.0 1.66s
25 -363.3977100157 -9.09 -4.37 0.000 3.648 1.0 1.75s
26 -363.3977100166 -9.05 -4.39 0.000 3.648 1.0 2.20s
27 -363.3977100164 + -9.69 -4.35 0.000 3.648 1.0 1.68s
28 -363.3977100169 -9.30 -4.23 0.000 3.648 1.0 1.66s
29 -363.3977100172 -9.50 -4.76 0.000 3.648 1.0 2.27s
30 -363.3977100174 -9.66 -4.80 0.000 3.648 1.2 1.75s
31 -363.3977100177 -9.46 -4.76 0.000 3.648 1.1 1.67s
32 -363.3977100178 -10.02 -5.37 0.000 3.648 1.0 1.73s
33 -363.3977100178 + -11.57 -5.50 0.000 3.648 2.6 2.55s
34 -363.3977100178 -11.43 -5.49 0.000 3.648 1.0 1.70s
35 -363.3977100178 -12.55 -5.44 0.000 3.648 1.0 1.66s
36 -363.3977100179 -10.89 -5.65 0.000 3.648 1.0 2.24s
37 -363.3977100179 -12.77 -5.73 0.000 3.648 1.0 1.70s
38 -363.3977100179 -11.74 -5.94 0.000 3.648 1.0 1.66s
39 -363.3977100179 + -12.47 -5.96 0.000 3.648 1.2 2.31s
40 -363.3977100179 -12.64 -6.00 0.000 3.648 1.0 1.65s
41 -363.3977100179 -12.29 -6.22 0.000 3.648 1.0 1.65s
Run band computation
bands_hub = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands_hub.εF > 0, bands_hub.eigenvalues[1])
band_gap = bands_hub.eigenvalues[1][lowest_unocc_band] - bands_hub.eigenvalues[1][lowest_unocc_band-1]0.11667605282942245With the electron localization introduced by the Hubbard term, the band gap has now opened, reflecting the experimental insulating behaviour of Nickel Oxide.
εF = bands_hub.εF
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands_hub; p, colors=[:blue, :blue], εrange)
plot_pdos(bands_hub; p, iatom=1, label="3D", colors=[:green, :purple], εrange)