Custom potential

We solve the 1D Gross-Pitaevskii equation with a custom potential. This is similar to Gross-Pitaevskii equation in 1D example and we show how to define local potentials attached to atoms, which allows for instance to compute forces. The custom potential is actually already defined as ElementGaussian in DFTK, and could be used as is.

using DFTK
using LinearAlgebra

First, we define a new element which represents a nucleus generating a Gaussian potential.

struct CustomPotential <: DFTK.Element
    α  # Prefactor
    L  # Width of the Gaussian nucleus
end

Some default values

CustomPotential() = CustomPotential(1.0, 0.5);

We extend the two methods providing access to the real and Fourier representation of the potential to DFTK.

function DFTK.local_potential_real(el::CustomPotential, r::Real)
    -el.α / (√(2π) * el.L) * exp(- (r / el.L)^2 / 2)
end
function DFTK.local_potential_fourier(el::CustomPotential, p::Real)
    # = ∫ V(r) exp(-ix⋅p) dx
    -el.α * exp(- (p * el.L)^2 / 2)
end

We set up the lattice. For a 1D case we supply two zero lattice vectors

a = 10
lattice = a .* [[1 0 0.]; [0 0 0]; [0 0 0]];

In this example, we want to generate two Gaussian potentials generated by two "nuclei" localized at positions $x_1$ and $x_2$, that are expressed in $[0,1)$ in fractional coordinates. $|x_1 - x_2|$ should be different from $0.5$ to break symmetry and get nonzero forces.

x1 = 0.2
x2 = 0.8
positions = [[x1, 0, 0], [x2, 0, 0]]
gauss     = CustomPotential()
atoms     = [gauss, gauss];

We setup a Gross-Pitaevskii model

C = 1.0
α = 2;
n_electrons = 1  # Increase this for fun
terms = [Kinetic(),
         AtomicLocal(),
         LocalNonlinearity(ρ -> C * ρ^α)]
model = Model(lattice, atoms, positions; n_electrons, terms,
              spin_polarization=:spinless);  # use "spinless electrons"

We discretize using a moderate Ecut and run a SCF algorithm to compute forces afterwards. As there is no ionic charge associated to gauss we have to specify a starting density and we choose to start from a zero density.

basis = PlaneWaveBasis(model; Ecut=500, kgrid=(1, 1, 1))
ρ = zeros(eltype(basis), basis.fft_size..., 1)
scfres = self_consistent_field(basis; tol=1e-5, ρ)
scfres.energies

Energy breakdown (in Ha):
    Kinetic             0.0380292 
    AtomicLocal         -0.3163461
    LocalNonlinearity   0.1212605 

    total               -0.157056406913

Computing the forces can then be done as usual:

compute_forces(scfres)

2-element Vector{StaticArraysCore.SVector{3, Float64}}:
 [-0.05567831127347074, -0.0, -0.0]
 [0.0556793995479891, -0.0, -0.0]

Extract the converged total local potential

tot_local_pot = DFTK.total_local_potential(scfres.ham)[:, 1, 1]; # use only dimension 1

Extract other quantities before plotting them

ρ = scfres.ρ[:, 1, 1, 1]        # converged density, first spin component
ψ_fourier = scfres.ψ[1][:, 1]   # first k-point, all G components, first eigenvector

101-element Vector{ComplexF64}:
   -0.28329187744679446 + 0.9305128009688491im
   -0.02911477546305112 + 0.09563011405277796im
    0.03449560430767814 - 0.11330840456006157im
   0.014985805948974066 - 0.0492214487648363im
 -0.0026150211227613618 + 0.008590274409435033im
 -0.0039794921309811776 + 0.013071001169648684im
 -0.0005741864768656463 + 0.001885780674395922im
  0.0006387345386626497 - 0.0020979874172306354im
  0.0002751291839407951 - 0.0009036458912861393im
  -4.187087082811867e-5 + 0.00013753207986701363im
                        ⋮
  -4.187217445889493e-5 + 0.000137533893487507im
 0.00027510033201991603 - 0.0009036530656448524im
  0.0006387215942677287 - 0.0020979919743848397im
 -0.0005740657606829322 + 0.0018858185550444343im
  -0.003979371942350656 + 0.013071035001228743im
  -0.002615502700565146 + 0.008590127460497508im
   0.014984926385243907 - 0.049221717660160376im
    0.03449707740755474 - 0.11330795611131966im
  -0.029113916462129154 + 0.09563037548463296im

Transform the wave function to real space and fix the phase:

ψ = ifft(basis, basis.kpoints[1], ψ_fourier)[:, 1, 1]
ψ /= (ψ[div(end, 2)] / abs(ψ[div(end, 2)]));

using Plots
x = a * vec(first.(DFTK.r_vectors(basis)))
p = plot(x, real.(ψ), label="real(ψ)")
plot!(p, x, imag.(ψ), label="imag(ψ)")
plot!(p, x, ρ, label="ρ")
plot!(p, x, tot_local_pot, label="tot local pot")