Arbitrary floating-point types

Since DFTK is completely generic in the floating-point type in its routines, there is no reason to perform the computation using double-precision arithmetic (i.e.Float64). Other floating-point types such as Float32 (single precision) are readily supported as well. On top of that we already reported^[HLC2020] calculations in DFTK using elevated precision from DoubleFloats.jl or interval arithmetic using IntervalArithmetic.jl. In this example, however, we will concentrate on single-precision computations with Float32.

The setup of such a reduced-precision calculation is basically identical to the regular case, since Julia automatically compiles all routines of DFTK at the precision, which is used for the lattice vectors. Apart from setting up the model with an explicit cast of the lattice vectors to Float32, there is thus no change in user code required:

using DFTK

# Setup silicon lattice
a = 10.263141334305942  # lattice constant in Bohr
lattice = a / 2 .* [[0 1 1.]; [1 0 1.]; [1 1 0.]]
Si = ElementPsp(:Si; psp=load_psp("hgh/lda/Si-q4"))
atoms = [Si, Si]
positions = [ones(3)/8, -ones(3)/8]

# Cast to Float32, setup model and basis
model = model_DFT(lattice, atoms, positions; functionals=LDA())
basis = PlaneWaveBasis(convert(Model{Float32}, model), Ecut=7, kgrid=[4, 4, 4])

# Run the SCF
scfres = self_consistent_field(basis, tol=1e-3);

n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime
---   ---------------   ---------   ---------   ----   ------
  1   -7.900579929352                   -0.70    4.6   73.4ms
  2   -7.905018329620       -2.35       -1.52    1.0   45.0ms
  3   -7.905179023743       -3.79       -2.52    1.0   45.1ms
  4   -7.905209541321       -4.51       -2.83    2.5    115ms
  5   -7.905212402344       -5.62       -2.96    1.1   46.2ms
  6   -7.905212402344   +    -Inf       -4.53    1.0   45.4ms

To check the calculation has really run in Float32, we check the energies and density are expressed in this floating-point type:

scfres.energies

Energy breakdown (in Ha):
    Kinetic             3.1021342 
    AtomicLocal         -2.1988494
    AtomicNonlocal      1.7295818 
    Ewald               -8.3978958
    PspCorrection       -0.2946220
    Hartree             0.5530602 
    Xc                  -2.3986218

    total               -7.905212402344

eltype(scfres.energies.total)

Float32

eltype(scfres.ρ)

Float32