Crystal symmetries

Theory

In this discussion we will only describe the situation for a monoatomic crystal $\mathcal C \subset \mathbb R^3$, the extension being easy. A symmetry of the crystal is an orthogonal matrix $\widetilde{S}$ and a real-space vector $\widetilde{\tau}$ such that

\[\widetilde{S} \mathcal{C} + \widetilde{\tau} = \mathcal{C}.\]

The symmetries where $\widetilde{S} = 1$ and $\widetilde{\tau}$ is a lattice vector are always assumed and ignored in the following.

We can define a corresponding unitary operator $U$ on $L^2(\mathbb R^3)$ with action

\[ (Uu)(x) = u\left( \widetilde{S} x + \widetilde{\tau} \right).\]

We assume that the atomic potentials are radial and that any self-consistent potential also respects this symmetry, so that $U$ commutes with the Hamiltonian.

This operator acts on a plane-wave as

\[\begin{aligned} (U e^{iq\cdot x}) (x) &= e^{iq \cdot \widetilde{\tau}} e^{i (\widetilde{S}^T q) x}\\ &= e^{- i(S q) \cdot \tau } e^{i (S q) \cdot x} \end{aligned}\]

where we set

\[\begin{aligned} S &= \widetilde{S}^{T}\\ \tau &= -\widetilde{S}^{-1}\widetilde{\tau}. \end{aligned}\]

(these equations being also valid in reduced coordinates).

It follows that the Fourier transform satisfies

\[\widehat{Uu}(q) = e^{- iq \cdot \tau} \widehat u(S^{-1} q)\]

In particular, if $e^{ik\cdot x} u_{k}(x)$ is an eigenfunction, then by decomposing $u_k$ over plane-waves $e^{i G \cdot x}$ one can see that $e^{i(S^T k) \cdot x} (U u_k)(x)$ is also an eigenfunction: we can choose

\[u_{Sk} = U u_k.\]

This is used to reduce the computations needed. For a uniform sampling of the Brillouin zone (the reducible $k$-points), one can find a reduced set of $k$-points (the irreducible $k$-points) such that the eigenvectors at the reducible $k$-points can be deduced from those at the irreducible $k$-points.

Example

Let us demonstrate this in practice. We consider silicon, setup appropriately in the lattice and atoms objects as in Tutorial and to reach a fast execution, we take a small Ecut of 5 and a [4, 4, 4] Monkhorst-Pack grid. First we perform the DFT calculation disabling symmetry handling

model = model_LDA(lattice, atoms)
basis_nosym = PlaneWaveBasis(model, Ecut; kgrid=kgrid, use_symmetry=false)
scfres_nosym = @time self_consistent_field(basis_nosym, tol=1e-8)
n     Energy            Eₙ-Eₙ₋₁     ρout-ρin   Diag
---   ---------------   ---------   --------   ----
  1   -7.868374256427         NaN   1.87e-01    2.9
  2   -7.872765700546   -4.39e-03   2.86e-02    1.9
  3   -7.872865497888   -9.98e-05   2.51e-03    1.0
  4   -7.872877843188   -1.23e-05   7.28e-04    2.0
  5   -7.872878168872   -3.26e-07   2.20e-04    1.2
  6   -7.872878211156   -4.23e-08   1.45e-05    1.2
  7   -7.872878213110   -1.95e-09   3.38e-06    2.3
  4.071594 seconds (1.35 M allocations: 889.175 MiB, 2.89% gc time)

and then redo it using symmetry (the default):

basis_sym = PlaneWaveBasis(model, Ecut; kgrid=kgrid)
scfres_sym = @time self_consistent_field(basis_sym, tol=1e-8)
n     Energy            Eₙ-Eₙ₋₁     ρout-ρin   Diag
---   ---------------   ---------   --------   ----
  1   -7.868299000393         NaN   1.88e-01    3.7
  2   -7.872766007754   -4.47e-03   2.87e-02    1.8
  3   -7.872865586317   -9.96e-05   2.61e-03    1.0
  4   -7.872877871689   -1.23e-05   7.10e-04    2.0
  5   -7.872878174807   -3.03e-07   2.12e-04    1.2
  6   -7.872878211189   -3.64e-08   1.60e-05    1.3
  7   -7.872878213108   -1.92e-09   3.16e-06    2.2
  0.802379 seconds (229.52 k allocations: 159.750 MiB, 2.97% gc time)

Clearly both yield the same energy but the version employing symmetry is faster, since less $k$-points are explicitly treated:

(length(basis_sym.kpoints), length(basis_nosym.kpoints))
(10, 64)

Both SCFs would even agree in the convergence history if exact diagonalization was used for the eigensolver in each step of both SCFs. But since DFTK adjusts this diagtol value adaptively during the SCF to increase performance, a slightly different history is obtained. Try adding the keyword argument determine_diagtol=(args...; kwargs...) -> 1e-8 in each SCF call to fix the diagonalization tolerance to be 1e-8 for all SCF steps, which will result in an almost identical convergence history.

We can also explicitly verify both methods to yield the same density:

(norm(scfres_sym.ρ.real - scfres_nosym.ρ.real),
 norm(values(scfres_sym.energies) .- values(scfres_nosym.energies)))
(4.853878957531699e-6, 2.991888977660011e-6)

To demonstrate the mapping between k-points due to symmetry, we pick an arbitrary k-point in the irreducible Brillouin zone:

ikpt_irred = 2
kpt_irred_coord = basis_sym.kpoints[ikpt_irred].coordinate
basis_sym.ksymops[ikpt_irred]
6-element Array{Tuple{StaticArrays.SArray{Tuple{3,3},Int64,2,9},StaticArrays.SArray{Tuple{3},Float64,1,3}},1}:
 ([1 0 0; 0 1 0; 0 0 1], [0.0, 0.0, 0.0])
 ([0 0 1; 1 0 0; 0 1 0], [0.0, 0.0, 0.0])
 ([0 1 0; 0 0 1; 1 0 0], [0.0, 0.0, 0.0])
 ([0 0 -1; 0 -1 0; -1 0 0], [0.0, 0.0, 0.0])
 ([0 -1 0; -1 0 0; 0 0 -1], [0.0, 0.0, 0.0])
 ([-1 0 0; 0 0 -1; 0 -1 0], [0.0, 0.0, 0.0])

This is a list of all symmetries operations $(S, \tau)$ that can be used to map this irreducible $k$-point to reducible $k$-points. Let's pick the third symmetry operation of this $k$-point and check.

S, τ = basis_sym.ksymops[ikpt_irred][3]
kpt_red_coord = S * basis_sym.kpoints[ikpt_irred].coordinate
ikpt_red = findfirst(kcoord -> kcoord ≈ kpt_red_coord,
                     [k.coordinate for k in basis_nosym.kpoints])
[scfres_sym.eigenvalues[ikpt_irred] scfres_nosym.eigenvalues[ikpt_red]]
7×2 Array{Float64,2}:
 -0.12437    -0.12437
  0.0951517   0.095152
  0.176058    0.176058
  0.231686    0.231686
  0.366275    0.366276
  0.397683    0.397683
  0.405286    0.405285